# Copyright 1999-2010 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI=2
inherit eutils games versionator

MY_PV=${PV}-0602
MY_MV=$(get_major_version)
DESCRIPTION="Excalibur: Morgana's Revenge, based on the Aleph One engine"
HOMEPAGE="http://emr.excaliburworld.com/emr3/index.html"
SRC_URI="mirror://sourceforge/${PN}${MY_MV}/${PN}-${MY_PV}.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc"

RDEPEND="games-fps/alephone"
DEPEND=""

src_prepare() {
	# Prepare the emr script
	sed -e s=@ALEPHONE@=alephone= \
	    -e s=@DATADIR@="${GAMES_DATADIR}"= < emr.in > emr \
	    || die "sed failed"

	# Fix the emr.6 man page
	sed -e s=@DATADIR@="${GAMES_DATADIR}"= < emr.6.in > emr.6 \
	    || die "sed failed"

	# Avoid (now useless) Makefile
	rm Makefile
}

src_install() {
	dogamesbin ${PN}

	doman ${PN}.6

	insinto "${GAMES_DATADIR}"/${PN}
	doins -r share-emr/*

	dodoc README

	if use doc; then
		dohtml share-doc-emr/Read\ Me.html
		dohtml -r share-doc-emr/docs/{index.html,main,rw_common}
	fi

	doicon ${PN}.png
	make_desktop_entry ${PN} "Excalibur: Morgana's Revenge"

	prepgamesdirs
}